Bug 1310:

- New lofar_package() macro replaces lofar_add_package(). The new macro
  supports recursive addition of LOFAR packages, using the dependencies passed
  as arguments. For example: 
    lofar_package(Blob 1.0 DEPENDS Common) 
  will add the package Common to the build (unless it was already added).
  This new features enables a "top-down" package specification order, which is
  required for building subsystems.

- New lofar_add_package() macro replaces lofar_add_subdirectory(). This macro
  uses a ${pkg}_SOURCE_DIR variable to locate the source directory of the
  package <pkg>. This information is needed, as we cannot simply include
  actual subdirectories anymore, because dependent package(s) might be located
  in a different directory tree.

- New file LofarPackageList.cmake, which sets the ${pkg}_SOURCE_DIR variables.
  This file is generated by a script gen_LofarPackageList_cmake.sh, which must
  be rerun when LOFAR packages are added, moved, or removed.

CEP/CMakeLists.txt

@@ -34,15 +34,15 @@ include(LofarGeneral)
 ## ---------------------------------------------------------------------------
 ## Subdirectories
 ## ---------------------------------------------------------------------------
-lofar_add_subdirectory(MWCommon)
-lofar_add_subdirectory(MS)
-lofar_add_subdirectory(ParmDB)
-lofar_add_subdirectory(Calibration)
-lofar_add_subdirectory(DP3)
-lofar_add_subdirectory(Imager)
+lofar_add_package(MWCommon)
+lofar_add_package(MS)
+lofar_add_package(ParmDB)
+lofar_add_package(Calibration)
+lofar_add_package(DP3)
+lofar_add_package(Imager)
 
-lofar_add_subdirectory(Pipeline)
-lofar_add_subdirectory(pyparmdb)
+lofar_add_package(Pipeline)
+lofar_add_package(pyparmdb)
 
 ## ---------------------------------------------------------------------------
 ## Generate configuration header file.

CEP/Calibration/BBSControl/CMakeLists.txt

@@ -31,9 +31,9 @@ include(LofarInit)
 project(BBSControl)
 include(LofarGeneral)
 
-include(LofarAddPackage)
+include(LofarPackage)
 # Do not split the following line, otherwise makeversion will fail!
-lofar_add_package(${PROJECT_NAME} 1.0 DEPENDS BBSKernel Blob Common MWCommon ParmDB PLC Transport)
+lofar_package(${PROJECT_NAME} 1.0 DEPENDS BBSKernel Blob Common MWCommon ParmDB PLC Transport)
 
 ## ---------------------------------------------------------------------------
 ## External packages

CEP/Calibration/BBSControl/scripts/CMakeLists.txt

+# $Id$
+#
+# Copyright (C) 2008-2009
+# ASTRON (Netherlands Foundation for Research in Astronomy)
+# P.O.Box 2, 7990 AA Dwingeloo, The Netherlands, seg@astron.nl
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
+
+include(PythonInstall)
+
+# Python modules.
+python_install(
+  __init__.py 
+  solfetch.py
+  solplot.py
+  solflag.py
+  DESTINATION lofar/solutions)

CEP/Calibration/BBSKernel/CMakeLists.txt

@@ -31,8 +31,8 @@ include(LofarInit)
 project(BBSKernel)
 include(LofarGeneral)
 
-include(LofarAddPackage)
-lofar_add_package(${PROJECT_NAME} 1.0 DEPENDS Blob Common ParmDB)
+include(LofarPackage)
+lofar_package(${PROJECT_NAME} 1.0 DEPENDS Blob Common ParmDB)
 
 ## ---------------------------------------------------------------------------
 ## External packages

CEP/Calibration/CMakeLists.txt

@@ -34,8 +34,8 @@ include(LofarGeneral)
 ## ---------------------------------------------------------------------------
 ## Subdirectories
 ## ---------------------------------------------------------------------------
-lofar_add_subdirectory(BBSKernel)
-lofar_add_subdirectory(BBSControl)
+lofar_add_package(BBSKernel)
+lofar_add_package(BBSControl)
 
 ## ---------------------------------------------------------------------------
 ## Generate configuration header file.

CEP/DP3/CMakeLists.txt

@@ -34,8 +34,8 @@ include(LofarGeneral)
 ## ---------------------------------------------------------------------------
 ## Subdirectories
 ## ---------------------------------------------------------------------------
-lofar_add_subdirectory(DPPP)
-lofar_add_subdirectory(SPWCombine)
+lofar_add_package(DPPP)
+lofar_add_package(SPWCombine)
 
 ## ---------------------------------------------------------------------------
 ## Generate configuration header file.

CEP/DP3/DPPP/CMakeLists.txt

@@ -31,8 +31,8 @@ include(LofarInit)
 project(DPPP)
 include(LofarGeneral)
 
-include(LofarAddPackage)
-lofar_add_package(${PROJECT_NAME} 1.0 DEPENDS Common MS PLC)
+include(LofarPackage)
+lofar_package(${PROJECT_NAME} 1.0 DEPENDS Common MS PLC)
 
 ## ---------------------------------------------------------------------------
 ## External packages

CEP/Imager/CMakeLists.txt

@@ -34,8 +34,8 @@ include(LofarGeneral)
 ## ---------------------------------------------------------------------------
 ## Subdirectories
 ## ---------------------------------------------------------------------------
-lofar_add_subdirectory(MWControl)
-lofar_add_subdirectory(MWImager)
+lofar_add_package(MWControl)
+lofar_add_package(MWImager)
 
 ## ---------------------------------------------------------------------------
 ## Generate configuration header file.

CEP/Imager/MWControl/CMakeLists.txt

@@ -31,9 +31,9 @@ include(LofarInit)
 project(MWControl)
 include(LofarGeneral)
 
-include(LofarAddPackage)
+include(LofarPackage)
 # Do not split the following line, otherwise makeversion will fail!
-lofar_add_package(${PROJECT_NAME} 0.1 DEPENDS Common Blob MWCommon ParmDB BBSKernel)
+lofar_package(${PROJECT_NAME} 0.1 DEPENDS Common Blob MWCommon ParmDB BBSKernel)
 
 ## ---------------------------------------------------------------------------
 ## External packages

CEP/Imager/MWImager/CMakeLists.txt

@@ -31,8 +31,8 @@ include(LofarInit)
 project(MWImager)
 include(LofarGeneral)
 
-include(LofarAddPackage)
-lofar_add_package(${PROJECT_NAME} 0.1 DEPENDS Common MWCommon)
+include(LofarPackage)
+lofar_package(${PROJECT_NAME} 0.1 DEPENDS Common MWCommon)
 
 ## ---------------------------------------------------------------------------
 ## External packages

CEP/MS/CMakeLists.txt

@@ -31,8 +31,8 @@ include(LofarInit)
 project(MS)
 include(LofarGeneral)
 
-include(LofarAddPackage)
-lofar_add_package(${PROJECT_NAME} 0.1 DEPENDS Common Blob MWCommon)
+include(LofarPackage)
+lofar_package(${PROJECT_NAME} 0.1 DEPENDS Common Blob MWCommon)
 
 ## ---------------------------------------------------------------------------
 ## External packages

CEP/MWCommon/CMakeLists.txt

@@ -31,8 +31,8 @@ include(LofarInit)
 project(MWCommon)
 include(LofarGeneral)
 
-include(LofarAddPackage)
-lofar_add_package(${PROJECT_NAME} 0.1 DEPENDS Common Blob)
+include(LofarPackage)
+lofar_package(${PROJECT_NAME} 0.1 DEPENDS Common Blob)
 
 ## ---------------------------------------------------------------------------
 ## External packages

CEP/ParmDB/CMakeLists.txt

@@ -31,8 +31,8 @@ include(LofarInit)
 project(ParmDB)
 include(LofarGeneral)
 
-include(LofarAddPackage)
-lofar_add_package(${PROJECT_NAME} 1.0 DEPENDS Common Blob MWCommon)
+include(LofarPackage)
+lofar_package(${PROJECT_NAME} 1.0 DEPENDS Common Blob MWCommon)
 
 ## ---------------------------------------------------------------------------
 ## External packages

CEP/Pipeline/CMakeLists.txt

@@ -31,8 +31,8 @@ include(LofarInit)
 project(Pipeline)
 include(LofarGeneral)
 
-include(LofarAddPackage)
-lofar_add_package(${PROJECT_NAME} 0.1 DEPENDS pytools)
+include(LofarPackage)
+lofar_package(${PROJECT_NAME} 0.1 DEPENDS pytools)
 
 ## ---------------------------------------------------------------------------
 ## External packages

CEP/pyparmdb/CMakeLists.txt

@@ -31,8 +31,8 @@ include(LofarInit)
 project(pyparmdb)
 include(LofarGeneral)
 
-include(LofarAddPackage)
-lofar_add_package(${PROJECT_NAME} 1.0 DEPENDS Common ParmDB)
+include(LofarPackage)
+lofar_package(${PROJECT_NAME} 1.0 DEPENDS Common ParmDB)
 
 ## ---------------------------------------------------------------------------
 ## External packages

CMake/LofarAddPackage.cmake

-#  $Id$
-#
-#  Copyright (C) 2008-2009
-#  ASTRON (Netherlands Foundation for Research in Astronomy)
-#  P.O.Box 2, 7990 AA Dwingeloo, The Netherlands, seg@astron.nl
-#
-#  This program is free software; you can redistribute it and/or modify
-#  it under the terms of the GNU General Public License as published by
-#  the Free Software Foundation; either version 2 of the License, or
-#  (at your option) any later version.
-#
-#  This program is distributed in the hope that it will be useful,
-#  but WITHOUT ANY WARRANTY; without even the implied warranty of
-#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
-#  GNU General Public License for more details.
-#
-#  You should have received a copy of the GNU General Public License
-#  along with this program; if not, write to the Free Software
-#  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
-
-# --------------------------------------------------------------------------
-# lofar_add_package(<name> [version] [DEPENDS <depend> [depend] ...])
-#
-# Add a LOFAR package. 
-#
-# This function performs the following actions:
-# - Create a custom target for package <name>, using add_custom_target().
-# - If package <name> has dependencies, then, for each dependency <dep>:
-#   - add a dependency of package <name> on package <dep>
-#   - add the list of include directories of <dep> to that of <name>
-# - Add a preprocessor definition for LOFARLOGGER_PACKAGE
-#
-# This function sets the following variables in the parent scope:
-#   ${name}_VERSION       Version number of package <name>
-#   ${name}_DEPENDENCIES  List of packages that package <name> depends on.
-#
-# --------------------------------------------------------------------------
-function(lofar_add_package _name)
-
-  set(_errmsg 
-    "Wrong arguments supplied to lofar_add_package().\n"
-    "Usage: lofar_add_package(name [version] [DEPENDS depend ...])\n")
-
-  # Print message to console if configuring verbose.
-  if(LOFAR_VERBOSE_CONFIGURE)
-    message(STATUS "Adding package ${_name}...")
-  endif(LOFAR_VERBOSE_CONFIGURE)
-
-  # If arguments were given, then the first could be a version number.
-  if(ARGC GREATER 1)
-    list(GET ARGV 1 _version)
-    string(REGEX MATCH "^[0-9]+(\\.[0-9]+)*$" _version ${_version})
-  endif(ARGC GREATER 1)
-  
-  # If two arguments were given, then the second must be a version number.
-  if(ARGC EQUAL 2 AND NOT _version)
-    message(FATAL_ERROR ${_errmsg})
-  endif(ARGC EQUAL 2 AND NOT _version)
-
-  # If more than two arguments were given, then search for the DEPENDS
-  # keyword, which must be present.
-  if(ARGC GREATER 2)
-    list(FIND ARGV DEPENDS _idx)
-    if(_idx EQUAL -1)
-      message(FATAL_ERROR ${_errmsg})
-    endif(_idx EQUAL -1)
-    # Let _idx point to the first argument of DEPENDS
-    math(EXPR _idx "${_idx}+1")
-    if(NOT _idx LESS ARGC)
-      # Missing arguments after DEPENDS
-      message(FATAL_ERROR ${_errmsg})
-    endif(NOT _idx LESS ARGC)
-    # Add dependencies to the dependency list
-    while(_idx LESS ARGC)
-      list(GET ARGV ${_idx} _dep)
-      list(APPEND _dependencies ${_dep})
-      math(EXPR _idx "${_idx}+1")
-    endwhile(_idx LESS ARGC)
-  endif(ARGC GREATER 2)
-
-  # Create a custom target for package <name> that depends on 'all'.
-  add_custom_target(${_name} ALL)
-
-  # For each package <pkg> that this package depends on:
-  # - add a dependency of package <name> on package <pkg>
-  # - add the list of include directories of <pkg> to that of package <name>
-  foreach(_dep ${_dependencies})
-    get_directory_property(_dirs 
-      DIRECTORY ${${_dep}_SOURCE_DIR} INCLUDE_DIRECTORIES)
-    add_dependencies(${_name} ${_dep})
-#    message(STATUS "set(BUILD_${_dep} TRUE CACHE BOOL \"Build ${_dep}?\"")
-#    set(BUILD_${_dep} TRUE CACHE BOOL "Build ${_dep}?")
-    include_directories(${_dirs})
-  endforeach(_dep ${_dependencies})
-
-  # Set LOFAR Logger package name to the current project
-  string(REGEX REPLACE "^${LOFAR_ROOT}" "" _pkg "${${_name}_SOURCE_DIR}")
-  string(REGEX REPLACE "^/" "" _pkg "${_pkg}")
-  string(REPLACE "/" "." _pkg "${_pkg}")
-  add_definitions(-DLOFARLOGGER_PACKAGE="${_pkg}")
-
-  # Export variables to the parent scope
-  set(LOFAR_PACKAGE_NAME ${_name} PARENT_SCOPE)
-  set(${_name}_VERSION ${_version} PARENT_SCOPE)
-  set(${_name}_DEPENDENCIES ${_dependencies} PARENT_SCOPE)
-
-endfunction(lofar_add_package _name)
-  

CMake/LofarMacros.cmake

@@ -31,7 +31,6 @@
 #   lofar_add_executable(name)
 #   lofar_add_library(name)
 #   lofar_add_sbin_program(name)
-#   lofar_add_subdirectory(name)
 #   lofar_add_test(name)
 #   lofar_get_date(date)
 #   lofar_get_hostname(name)
@@ -171,32 +170,6 @@ if(NOT DEFINED LOFAR_MACROS_INCLUDED)
   endmacro(lofar_add_sbin_program _name)
 
 
-  # --------------------------------------------------------------------------
-  # lofar_add_subdirectory(srcdir [bindir] [REQUIRED])
-  #
-  # Add a subdirectory like add_subdirectory() does.
-  # Furthermore:
-  # - It is not an error is the directory does not exist, unless the REQUIRED
-  #   keyword is specified.
-  # - If [bindir] is not supplied, it is determined on the fly, so the user
-  #   doesn't have to bother when specifying an out-of-tree source.
-  # --------------------------------------------------------------------------
-  macro(lofar_add_subdirectory srcdir)
-    get_filename_component(_srcdir ${srcdir} ABSOLUTE)
-    string(REGEX MATCH ";?REQUIRED.*" _required "${ARGN}")
-    string(REPLACE "${_required}" "" _bindir "${ARGN}")
-    if(_bindir MATCHES "^.+$")
-      get_filename_component(_bindir ${_bindir} ABSOLUTE)
-    else(_bindir MATCHES "^.+$")
-      string(REGEX REPLACE
-        ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR} _bindir ${_srcdir})
-    endif(_bindir MATCHES "^.+$")
-    if(_required OR EXISTS ${_srcdir})
-      add_subdirectory(${_srcdir} ${_bindir})
-    endif(_required OR EXISTS ${_srcdir})
-  endmacro(lofar_add_subdirectory)
-
-
   # --------------------------------------------------------------------------
   # lofar_add_test(name [source ...] [DEPENDS depend ...])
   #

CMake/LofarPackage.cmake

+#  $Id$
+#
+#  Copyright (C) 2008-2009
+#  ASTRON (Netherlands Foundation for Research in Astronomy)
+#  P.O.Box 2, 7990 AA Dwingeloo, The Netherlands, seg@astron.nl
+#
+#  This program is free software; you can redistribute it and/or modify
+#  it under the terms of the GNU General Public License as published by
+#  the Free Software Foundation; either version 2 of the License, or
+#  (at your option) any later version.
+#
+#  This program is distributed in the hope that it will be useful,
+#  but WITHOUT ANY WARRANTY; without even the implied warranty of
+#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+#  GNU General Public License for more details.
+#
+#  You should have received a copy of the GNU General Public License
+#  along with this program; if not, write to the Free Software
+#  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
+
+# --------------------------------------------------------------------------
+# LOFAR package related macros
+#
+# Defines the following macros:
+#   lofar_add_package(pkg [srcdir] [REQUIRED])
+#   lofar_package(<name> [version] [DEPENDS <depend> [depend] ...])
+# --------------------------------------------------------------------------
+
+
+# --------------------------------------------------------------------------
+# lofar_add_package(pkg [srcdir] [REQUIRED])
+#
+# Add a LOFAR package to the build, unless it is excluded from the build
+# (i.e., option BUILD_<pkg> is OFF).
+#
+# Adding a package implies:
+# - If the target <pkg> is not yet defined, and if the package source
+#   directory exists:
+#   - define the option BUILD_<pkg>
+#   - add a custom target <pkg>
+#   - add the source directory to the build
+# - If the target <pkg> is defined:
+#   - add a dependency of the current project on package <pkg>
+#
+# Furthermore:
+# - if [srcdir] is not supplied, <pkg>_SOURCE_DIR is used as directory name,
+#   unless <pkg>_SOURCE_DIR is undefined, in which case <pkg> is used.
+# - it is not an error if the package source directory does not exist, 
+#   unless the REQUIRED keyword is specified.
+# --------------------------------------------------------------------------
+macro(lofar_add_package _pkg)
+  if(NOT DEFINED BUILD_${_pkg} OR BUILD_${_pkg})
+    if(NOT TARGET ${_pkg})
+      string(REGEX REPLACE ";?REQUIRED$" "" _srcdir "${ARGN}")
+      string(REGEX MATCH "REQUIRED$" _required "${ARGN}")
+      if(_srcdir MATCHES "^$")
+        if(DEFINED ${_pkg}_SOURCE_DIR)
+          set(_srcdir ${${_pkg}_SOURCE_DIR})
+        else(DEFINED ${_pkg}_SOURCE_DIR)
+#          message(STATUS "Variable ${_pkg}_SOURCE_DIR is undefined")
+          set(_srcdir ${_pkg})
+        endif(DEFINED ${_pkg}_SOURCE_DIR)
+      endif(_srcdir MATCHES "^$")
+      get_filename_component(_srcdir ${_srcdir} ABSOLUTE)
+      string(REGEX REPLACE
+        ${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR} _bindir ${_srcdir})
+      if(EXISTS ${_srcdir})
+        option(BUILD_${_pkg} "Build package ${_pkg}?" ON)
+        mark_as_advanced(BUILD_${_pkg})
+        message(STATUS "Adding package ${_pkg}...")
+        add_custom_target(${_pkg})
+        add_subdirectory(${_srcdir} ${_bindir})
+      else(EXISTS ${_srcdir})
+        set(_errmsg "Source package `${_pkg}' not found! "
+          "Directory ${_srcdir} does not exist")
+        if(_required)
+          message(FATAL_ERROR ${_errmsg})
+        else(_required)
+          message(STATUS ${_errmsg})
+        endif(_required)
+      endif(EXISTS ${_srcdir})
+    endif(NOT TARGET ${_pkg})
+    if(TARGET ${_pkg})
+      add_dependencies(${LOFAR_PACKAGE_NAME} ${_pkg})
+    endif(TARGET ${_pkg})
+  endif(NOT DEFINED BUILD_${_pkg} OR BUILD_${_pkg})
+endmacro(lofar_add_package _pkg)
+
+
+# --------------------------------------------------------------------------
+# lofar_package(<pkg> [version] [DEPENDS <depend> [depend] ...])
+#
+# Define a LOFAR package. 
+#
+# This macro sets the following variables:
+#   LOFAR_PACKAGE_NAME   Name of package <pkg>
+#   ${pkg}_VERSION       Version number of package <pkg>
+#   ${pkg}_DEPENDENCIES  List of packages that package <pkg> depends on.
+#
+# Each dependent package is added to the build. If any of these packages is
+# excluded from the build (e.g., because BUILD_<dep> is OFF), then package
+# <pkg> will also be excluded from the build.
+#
+# The include directories of each dependent package will be added to the
+# include directories of package <pkg>. This is needed, because CMake does not
+# retain the include path across source directories.
+#
+# A preprocessor definition for LOFARLOGGER_PACKAGE is added.
+# --------------------------------------------------------------------------
+macro(lofar_package _pkg)
+
+  set(_errmsg 
+    "Wrong arguments supplied to lofar_package().\n"
+    "Usage: lofar_package(pkg [version] [DEPENDS depend ...])\n")
+
+  # Define a target for the current package, if it is not defined yet.
+  if(NOT TARGET ${_pkg})
+    add_custom_target(${_pkg})
+  endif(NOT TARGET ${_pkg})
+
+  # Use LOFAR_PACKAGE_NAME to store the name of the current LOFAR package
+  set(LOFAR_PACKAGE_NAME ${_pkg})
+
+  # Get the optional version number; a string of dot-separated numbers
+  string(REGEX REPLACE ";?DEPENDS.*" "" ${_pkg}_VERSION "${ARGN}")
+  if(NOT ${_pkg}_VERSION MATCHES "^([0-9]+(\\.[0-9]+)*)?$")
+    message(FATAL_ERROR ${_errmsg})
+  endif(NOT ${_pkg}_VERSION MATCHES "^([0-9]+(\\.[0-9]+)*)?$")
+
+  # Get the optional package dependencies
+  string(REGEX MATCH "DEPENDS;?.*" _depends "${ARGN}")
+  if(_depends MATCHES "^.+$")
+    string(REGEX REPLACE "DEPENDS;?" "" ${_pkg}_DEPENDENCIES "${_depends}")
+    if(${_pkg}_DEPENDENCIES MATCHES "^$")
+      message(FATAL_ERROR ${_errmsg})
+    endif(${_pkg}_DEPENDENCIES MATCHES "^$")
+  endif(_depends MATCHES "^.+$")
+
+  if(LOFAR_VERBOSE_CONFIGURE)
+    message(STATUS "  ${_pkg} version: ${${_pkg}_VERSION}")
+    message(STATUS "  ${_pkg} dependencies: ${${_pkg}_DEPENDENCIES}")
+  endif(LOFAR_VERBOSE_CONFIGURE)
+
+  # Add all packages that <pkg> depends on to the build. If any of these
+  # packages are excluded from the build (because BUILD_<dep> is OFF), then
+  # BUILD_<pkg> will also be set to OFF and an error is raised.
+  foreach(_dep ${${_pkg}_DEPENDENCIES})
+
+    # Break out of foreach-loop if building of package <pkg> is disabled.
+    if(DEFINED BUILD_${_pkg} AND NOT BUILD_${_pkg})
+      break()
+    endif(DEFINED BUILD_${_pkg} AND NOT BUILD_${_pkg})
+
+    # Add package <dep> to the build. Don't worry about multiple inclusion;
+    # lofar_add_package() will guard against it.
+    lofar_add_package(${_dep})# REQUIRED)
+
+    # If building of dependent package <dep> is enabled, then add the list
+    # of include directories of <dep> to that of package <pkg>, else disable
+    # building of package <pkg> as well and raise an error.
+    if(BUILD_${_dep})
+      get_directory_property(_dirs
+        DIRECTORY ${${_dep}_SOURCE_DIR} INCLUDE_DIRECTORIES)
+      include_directories(${_dirs})
+    else(BUILD_${_dep})
+      set(BUILD_${_pkg} OFF CACHE BOOL "Build package ${_pkg}" FORCE)
+      message(SEND_ERROR "Package `${_dep}' is excluded from the build, but "
+        "`${_pkg}' depends on it. Package `${_pkg}' will be excluded as well!")
+    endif(BUILD_${_dep})
+
+  endforeach(_dep ${${_pkg}_DEPENDENCIES})
+
+  # Add a preprocessor definition for the LOFAR Logger package
+  string(REGEX REPLACE "^${LOFAR_ROOT}" "" _lpkg "${${_pkg}_SOURCE_DIR}")
+  string(REGEX REPLACE "^/" "" _lpkg "${_lpkg}")
+  string(REPLACE "/" "." _lpkg "${_lpkg}")
+  add_definitions(-DLOFARLOGGER_PACKAGE="${_lpkg}")
+  
+endmacro(lofar_package)
+

CMake/LofarPackageList.cmake

+#
+# Generated by gen_LofarPackageList_cmake.sh at Wed Oct  7 15:43:03 CEST 2009
+#
+#                            ---- DO NOT EDIT ----
+#
+#  This file creates for each LOFAR package a variable containing the relative
+#  path to its source directory. 
+#
+#  ATTENTION: This file must be included BEFORE the first call of the
+#  lofar_package() macro; either directly, or indirectly.
+#
+#  NOTE: This file must be kept up-to-date when project directories are added,
+#  moved, or deleted. Use gen_LofarPackageList_cmake.sh to do so.
+#
+if(NOT DEFINED LOFAR_PACKAGE_LIST_INCLUDED)
+  set(LOFAR_PACKAGE_LIST_INCLUDED TRUE)
+  set(MS_SOURCE_DIR CEP/MS)
+  set(DPPP_SOURCE_DIR CEP/DP3/DPPP)
+  set(DP3_SOURCE_DIR CEP/DP3)
+  set(MWCommon_SOURCE_DIR CEP/MWCommon)
+  set(MWImager_SOURCE_DIR CEP/Imager/MWImager)
+  set(Imager_SOURCE_DIR CEP/Imager)
+  set(MWControl_SOURCE_DIR CEP/Imager/MWControl)
+  set(Pipeline_SOURCE_DIR CEP/Pipeline)
+  set(ParmDB_SOURCE_DIR CEP/ParmDB)
+  set(CEP_SOURCE_DIR CEP)
+  set(BBSControl_SOURCE_DIR CEP/Calibration/BBSControl)
+  set(Calibration_SOURCE_DIR CEP/Calibration)
+  set(BBSKernel_SOURCE_DIR CEP/Calibration/BBSKernel)
+  set(pyparmdb_SOURCE_DIR CEP/pyparmdb)
+  set(ALC_SOURCE_DIR LCS/ACC/ALC)
+  set(PLC_SOURCE_DIR LCS/ACC/PLC)
+  set(ACC_SOURCE_DIR LCS/ACC)
+  set(AMC_SOURCE_DIR LCS/AMC)
+  set(AMCBase_SOURCE_DIR LCS/AMC/AMCBase)
+  set(AMCImpl_SOURCE_DIR LCS/AMC/AMCImpl)
+  set(Blob_SOURCE_DIR LCS/Blob)
+  set(Common_SOURCE_DIR LCS/Common)
+  set(pytools_SOURCE_DIR LCS/pytools)
+  set(Tools_SOURCE_DIR LCS/Tools)
+  set(ApplCommon_SOURCE_DIR LCS/ApplCommon)
+  set(Stream_SOURCE_DIR LCS/Stream)
+  set(pyparameterset_SOURCE_DIR LCS/pyparameterset)
+  set(LCS_SOURCE_DIR LCS)
+  set(Transport_SOURCE_DIR LCS/Transport)
+  set(Firmware-Tools_SOURCE_DIR LCU/Firmware/tools)
+  set(Firmware_SOURCE_DIR LCU/Firmware)
+  set(LCU_SOURCE_DIR LCU)
+  set(StationTest_SOURCE_DIR LCU/StationTest)
+  set(BS_Protocol_SOURCE_DIR MAC/APL/PAC/BS_Protocol)
+  set(Beam_Server_SOURCE_DIR MAC/APL/PAC/Beam_Server)
+  set(SHMInfo_Server_SOURCE_DIR MAC/APL/PAC/SHMInfo_Server)
+  set(PAC_SOURCE_DIR MAC/APL/PAC)
+  set(Cal_Server_SOURCE_DIR MAC/APL/PAC/Cal_Server)
+  set(CAL_Protocol_SOURCE_DIR MAC/APL/PAC/CAL_Protocol)
+  set(PIC_SOURCE_DIR MAC/APL/PIC)
+  set(RSP_Protocol_SOURCE_DIR MAC/APL/PIC/RSP_Protocol)
+  set(TBB_Protocol_SOURCE_DIR MAC/APL/PIC/TBB_Protocol)
+  set(RSP_Driver_SOURCE_DIR MAC/APL/PIC/RSP_Driver)
+  set(TBB_Driver_SOURCE_DIR MAC/APL/PIC/TBB_Driver)
+  set(CUDaemons_SOURCE_DIR MAC/APL/CUDaemons)
+  set(TestCtlr_SOURCE_DIR MAC/APL/TestCtlr)
+  set(CEPCU_SOURCE_DIR MAC/APL/CEPCU)
+  set(VHECR_SOURCE_DIR MAC/APL/VHECR)
+  set(MainCU_SOURCE_DIR MAC/APL/MainCU)
+  set(APL_SOURCE_DIR MAC/APL)
+  set(CURTDBDaemons_SOURCE_DIR MAC/APL/CURTDBDaemons)
+  set(StationCU_SOURCE_DIR MAC/APL/StationCU)
+  set(MD_Protocol_SOURCE_DIR MAC/APL/MD_Protocol)
+  set(TestSuite_SOURCE_DIR MAC/APL/TestSuite)
+  set(RTCCommon_SOURCE_DIR MAC/APL/RTCCommon)
+  set(RTDBCommon_SOURCE_DIR MAC/APL/RTDBCommon)
+  set(APLCommon_SOURCE_DIR MAC/APL/APLCommon)
+  set(GCFTM_SOURCE_DIR MAC/GCF/TM)
+  set(GCFPVSS_SOURCE_DIR MAC/GCF/PVSS)
+  set(GCFRTDB_SOURCE_DIR MAC/GCF/RTDB)
+  set(GCF_SOURCE_DIR MAC/GCF)
+  set(MACIO_SOURCE_DIR MAC/MACIO)
+  set(MACTools_SOURCE_DIR MAC/Tools)
+  set(Deployment_SOURCE_DIR MAC/Deployment)
+  set(MAC_SOURCE_DIR MAC)
+  set(Navigator2_SOURCE_DIR MAC/Navigator2)
+  set(OTB_SOURCE_DIR SAS/OTB)
+  set(jOTDB2_SOURCE_DIR SAS/OTB/jOTDB2)
+  set(OTDB_SOURCE_DIR SAS/OTDB)
+  set(SAS_SOURCE_DIR SAS)
+  set(FCNP_SOURCE_DIR RTCP/FCNP)
+  set(RTCP_SOURCE_DIR RTCP)
+  set(Interface_SOURCE_DIR RTCP/Interface)
+  set(RTCPTools_SOURCE_DIR RTCP/RTCPTools)
+  set(Storage_SOURCE_DIR RTCP/Storage)
+  set(IONProc_SOURCE_DIR RTCP/IONProc)
+  set(CNProc_SOURCE_DIR RTCP/CNProc)
+  set(SubSystems_SOURCE_DIR SubSystems)
+  set(CCU_MAC_SOURCE_DIR SubSystems/CCU_MAC)
+endif(NOT DEFINED LOFAR_PACKAGE_LIST_INCLUDED)

CMake/PythonInstall.cmake

@@ -19,11 +19,12 @@
 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
 
 
+# --------------------------------------------------------------------------
 # python_install(source1..sourceN DESTINATION install_dir)
 #
 # Install Python source files and byte-compile them in the directory
 # ${PYTHON_INSTALL_DIR}/${install_dir}.
-
+# --------------------------------------------------------------------------
 macro(python_install)
 
   # Precondition checks.